xhads/source/main.adb

-- Copyright (c) 2024 - Ognjen 'xolatile' Milan Robovic
--
-- GNU General Public Licence (version 3 or later)

pragma ada_2012;

--~with core, ui, effect, attribute, skill, resource, faction, might, magic, equipment, unit, construction, chad, deity, world, ai;
with core, ui, effect, attribute, skill, resource, faction, equipment, unit, construction, chad, world;

use core;

procedure main is

------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

	side_panel      : integer := 0;
	preview_width   : integer := 0;
	preview_height  : integer := 0;
	text_box_height : integer := 0;

	player : chad.data := (
		index      => chad.ognjen,
		attributes => (1, 2, 3, 4, 5, 6),
		skills     => (1, 2, 3, 4, 5, 6, 7, 8, 9, others => 0),
		resources  => (101, 103, 107, 109, 113, 127)
	);

                                             ------------------------------------------------------------------------------------------

	type view is (
		map_preview_panel,      status_preview_panel,   text_box_panel
	);

	view_icon : array (view) of sprite      := (others => (others => 0));
	view_list : array (view) of boolean     := (others => true);
	view_text : array (view) of long_string := (
		"Toggle map preview panel.                                               ",
		"Toggle status preview panel.                                            ",
		"Toggle text box panel.                                                  "
	);

	procedure swap_map_preview_panel    is begin view_list (map_preview_panel)    := not view_list (map_preview_panel);    end swap_map_preview_panel;
	procedure swap_status_preview_panel is begin view_list (status_preview_panel) := not view_list (status_preview_panel); end swap_status_preview_panel;
	procedure swap_text_box_panel       is begin view_list (text_box_panel)       := not view_list (text_box_panel);       end swap_text_box_panel;

	view_show : array (view) of access procedure := (
		swap_map_preview_panel'access,
		swap_status_preview_panel'access,
		swap_text_box_panel'access
	);

	game_title   :                        sprite;
	game_preview : array (world.biome) of sprite;

	switch : natural     := 0;
	choose : world.biome := world.grass;

                                             ------------------------------------------------------------------------------------------

	procedure check_move_camera_up is
	begin
		move_camera_up;
		camera.y := clip (camera.y, 0, world.map.height - 1);
		if world.map.clips (camera.x, camera.y) then
			increment (camera.y);
		end if;
	end check_move_camera_up;

	procedure check_move_camera_down is
	begin
		move_camera_down;
		camera.y := clip (camera.y, 0, world.map.height - 1);
		if world.map.clips (camera.x, camera.y) then
			decrement (camera.y);
		end if;
	end check_move_camera_down;

	procedure check_move_camera_left is
	begin
		move_camera_left;
		camera.x := clip (camera.x, 0, world.map.width  - 1);
		if world.map.clips (camera.x, camera.y) then
			increment (camera.x);
		end if;
	end check_move_camera_left;

	procedure check_move_camera_right is
	begin
		move_camera_right;
		camera.x := clip (camera.x, 0, world.map.width  - 1);
		if world.map.clips (camera.x, camera.y) then
			decrement (camera.x);
		end if;
	end check_move_camera_right;

	procedure ui_main_style is
	begin
		ui.active := ui.style'val ((ui.style'pos (ui.active) + 1) mod ui.style_count);
	end ui_main_style;

	procedure zoom_in  is begin zoom := 2; end zoom_in;
	procedure zoom_out is begin zoom := 1; end zoom_out;

	signal_list : constant array (signal_code) of access procedure := (
		signal_up          => check_move_camera_up'access,
		signal_down        => check_move_camera_down'access,
		signal_left        => check_move_camera_left'access,
		signal_right       => check_move_camera_right'access,
		signal_v           => ui_main_style'access,
		signal_kp_add      => zoom_in'access,
		signal_kp_subtract => zoom_out'access,
		signal_m           => world.reveal_map'access,
		others             => idle_skip'access
	);

                                             ------------------------------------------------------------------------------------------

	procedure main_menu is
	begin
		draw (game_preview (world.ash), center_x (game_preview (world.ash).width * 2), center_y (game_preview (world.ash).height * 2), factor => 2);
		draw (game_title,               center_x (game_title.width               * 2), center_y (game_title.height               * 2), factor => 2);
		--
		ui.write ("Main Menu", 0, 0);
		--
		ui.draw_check_box (0, 32, view_list (map_preview_panel),    "map_preview_panel");
		ui.draw_check_box (0, 64, view_list (status_preview_panel), "status_preview_panel");
		ui.draw_check_box (0, 96, view_list (text_box_panel),       "text_box_panel");
	end main_menu;

------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

begin

	dash;
	echo (comment, "Copyright (C) 2024 -- Ognjen 'xolatile' Milan Robovic");
	echo (comment, "Version -- 1.0.0");
	echo (comment, "License -- GNU/GPLv3+");
	echo (comment, "Xhads is free software, you can redistribute it and modify it under the terms of the GNU General Public License by Free Software Foundation.");
	dash;

	initialize;

	ui.active := ui.main;

	ui.configure;

	--~play (import_song (c_string ("./song/main_menu.ogg")).index);

	attribute.configure;
	skill.configure;
	resource.configure;
	--~might.configure;
	--~magic.configure;
	equipment.configure;
	unit.configure;
	construction.configure;
	chad.configure;
	world.configure;
	--~ai.configure;

	world.make (world.grass, 240, 180);

	dash;
	echo (success, "Successfully initialized game data, entering main gameplay loop.");
	dash;

	for index in view loop
		view_icon (index) := import_sprite ("./sprite/ui/icon/" & lowercase (view'image (index)) & ".png", 1, 1);
	end loop;

	game_title := import_sprite ("./sprite/game_title.png", 1, 1);

	for index in world.biome loop
		game_preview (index) := import_sprite ("./sprite/" & lowercase (world.biome'image (index)) & "land_preview.png", 1, 1);
	end loop;

                                             ------------------------------------------------------------------------------------------

	introduction_loop: loop
		synchronize;
		--
		exit when signal_mode = signal_space or cursor_mode = 2;
		--
		case signal_mode is
			when signal_none  => null;
			when signal_space => null;
			when others       => switch := (switch + 1) mod world.biome_count;
			                     choose := world.biome'val (switch);
		end case;
		--
		draw (game_preview (choose), center_x (game_preview (choose).width * 2), center_y (game_preview (choose).height * 2), factor => 2);
		draw (game_title,            center_x (game_title.width            * 2), center_y (game_title.height            * 2), factor => 2);
		--
		ui.write ("[-- Please press Spacebar to continue]", 0, center_y (24), (102, 102, 102, 255));
	end loop introduction_loop;

	cursor_mode := 0;

	main_menu_loop: loop
		synchronize;
		--
		exit when signal_mode = signal_space or cursor_mode = 2;
		--
		main_menu;
	end loop main_menu_loop;

	cursor_mode := 0;

	ui.active := ui.style'val (faction.enumeration'pos (chad.trait (player.index).kind) + 1);

	gameplay_loop: loop
		synchronize;
		--
		exit when engine_active = false;
		--
		if not view_list (status_preview_panel) then
			side_panel := 0;
		else
			side_panel := window_width / 4;
		end if;
		--
		preview_width   := window_width  - side_panel;
		preview_height  := window_height - text_box_height;
		text_box_height := 32;
		--
		world.draw;
		--
		if view_list (map_preview_panel) then
			ui.draw_menu (0, 0, preview_width, preview_height);
		end if;
		--
		if view_list (status_preview_panel) then
			ui.draw_tiny_menu (preview_width, 0, side_panel, preview_height);
			chad.draw_data    (player, preview_width + 32, 32);
			--~ui.draw_state_box (preview_width + 32, 32);
		end if;
		--
		if view_list (text_box_panel) then
			ui.draw_help_box (0, window_height - text_box_height, window_width - icon * (view'pos (view'last) + 1), text_box_height);
		end if;
		--
		for index in view loop
			ui.draw_icon (view_icon (index), view_text (index),
			              window_width - icon * (view'pos (view'last) + 1) + icon * view'pos (index),
			              window_height - text_box_height,
			              view_show (index));
		end loop;
		--
		resource.draw_points (player.resources, (preview_width - 4 * icon * resource.count) / 2, (if view_list (map_preview_panel) then icon else 0));
		--
		signal_list (signal_mode).all;
		--
		--~magic.menu (0, 0, true);
		--~might.menu (0, 0, true);
		--
		chad.draw_alice;
		--
		ui.write (framerate'image, window_width - 5 * core.icon + 3, window_height - 27);
		--
		ui.synchronize;
	end loop gameplay_loop;

	--~world.mapshot ("./test.png");

                                             ------------------------------------------------------------------------------------------

	deinitialize;

	dash;

end main;